***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 09, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PZ1AL20B A K 
.param
+vc0 = 1.446e-10	vc1 = 2.086e-11		vc2 = 1.000		vc3 = 4.103e-12		vc4 = 1.087e-1
+tc1 = 1.341e-2		tc2 = 1.031e-2		tc3 = 1.051e-2		tc4 = 1.321e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 1.705e-15		   n = 1.010		  rs = 1.049e-2
+ibv = 25e-3			 nbv = 1.0		  bv = 20
+ikf = 6.819e-1
***** capacitance parameter *****
+cjo = 2.116e-10		   m = 3.247e-1		  vj = 5.624e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.107		 xti = 3
+trs1 = 5.506e-4		trs2 = 6.203e-6		tikf = 5.0e-3
+tbv1 = 7.320e-4		tbv2 = -6.275e-9	
.ends PZ1AL20B
*$
